Sub 페이지선택인쇄()
 
    Dim 전체페이지 As Integer
    Dim 선택페이지() As String
    Dim 시작페이지 As Integer, 종료페이지 As Integer
    Dim 입력페이지 As String
    Dim 메시지 As String
    Dim i As Integer
 
    메시지 = "연속된 페이지는 ""-"" 구분 자로, " & vbCr
    메시지 = 메시지 & "떨어진 페이지는 "","" 구분자로 구분해 입력하세요!" & vbCr & vbCr
    메시지 = 메시지 & "예를 들면 1,2,3,5 페이지를 인쇄하려면 " & vbCr
    메시지 = 메시지 & "1-3,5와 같이 입력합니다."
 
    입력페이지 = Application.InputBox(메시지, "선택 페이지 인쇄")
    전체페이지 = ActiveSheet.PageSetup.Pages.Count
    
    If 전체페이지 > 0 Then
        
        선택페이지() = Split(입력페이지, ",")
        
        For i = 0 To UBound(선택페이지)
            
            If InStr(1, 선택페이지(i), "-") > 0 Then
                        
                시작페이지 = CInt(Left(선택페이지(i), InStr(1, 선택페이지(i), "-") - 1))
                종료페이지 = CInt(Mid(선택페이지(i), InStr(1, 선택페이지(i), "-") + 1))
                        
                ActiveSheet.PrintOut From:=시작페이지, To:=종료페이지
                
            Else
            
                If 전체페이지 >= CInt(선택페이지(i)) Then
                    
                    ActiveSheet.PrintOut From:=선택페이지(i), To:=선택페이지(i)
                    
                End If
                
            End If
 
        Next i
 
   End If
    
End Sub