Private Sub btn검색_Click()

    Dim 이름 As Range
    Dim 찾은이름 As Range
    Dim 직원레코드 As Range, 셀 As Range
    Dim 행 As Integer, 열 As Integer
    Dim 키워드 As String
    Dim 첫번째위치 As String
    Dim 리스트() As Variant

    키워드 = txt검색.Value

    If Len(키워드) > 0 Then
    
        Set 이름 = Range("B2").CurrentRegion.Columns(2)
        Set 찾은이름 = 이름.Find(What:=키워드, LookAt:=xlPart)
        
        If Not 찾은이름 Is Nothing Then
        
            첫번째위치 = 찾은이름.Address
            
            Do
                
                ReDim Preserve 리스트(3, 행)
                Set 직원레코드 = 찾은이름.Offset(, -1).Resize(1, 3)
                
                For Each 셀 In 직원레코드
                    리스트(열, 행) = 셀.Value
                    열 = 열 + 1
                Next
                
                행 = 행 + 1
                열 = 0
                
                Set 찾은이름 = 이름.FindNext(찾은이름)
                
            Loop Until 찾은이름 Is Nothing Or 찾은이름.Address = 첫번째위치
            
            With lst결과
                .ColumnCount = 3
                .ColumnWidths = "1.7cm;2.1cm;1.2cm"
                .Column = 리스트
            End With
                        
        Else
            
            MsgBox "검색 결과가 존재하지 않습니다."
            lst결과.Clear
                
        End If
        
    End If

End Sub